SWFObject add-on: MouseWheel on Mac

vkimone — Mon, 12 Feb 2007 08:21:41 +0000

관련사이트
http://blog.pixelbreaker.com/flash/swfmacmousewheel/
mac os 상에서의 Flash Player 는 마우스 휠을 감지하지 못한다. 따라서 이 문제를 해결하려면 플래시 내부에서 마우스 휠반응을 체크하는 것이 아니라 자바스크립트로 마우스 휠을 감지하여 플래시로 알려줘야 된다.

SWFMacMouseWheel 라는 자바스크립트 파일을 사용하여 플래시의 내부 함수를 호출한다.
그리고 플래시에서는 ExternalInterface를 사용하여 자바스립트에서 호출하는 함수를 받아서 마우스 휠 반응을 처리한다.

import flash.external.ExternalInterface;
import com.pixelbreaker.event.EventBroadcaster;
/**
* @author Gabriel Bucknall
*
* Class that supports using the mouseWheel on Mac OS, requires javascript class
* swfmacmousewheel.js
*/
class com.pixelbreaker.ui.MouseWheel
{
private static var isMac:Boolean;
private static var macBroadcaster:EventBroadcaster;
 
private static function main():Void
{
isMac = System.capabilities.os.toLowerCase().indexOf( "mac" ) != -1;
if( isMac )
{
macBroadcaster = new EventBroadcaster();
ExternalInterface.addCallback( "externalMouseEvent", MouseWheel, MouseWheel.externalMouseEvent );
}
}
/**
* Add a listener for using the mouseWheel
* obj param must have an "onMouseWheel" method to be called.
*/
public static function addListener( obj:Object )
{
if( !isMac ) MouseWheel.main();
if( isMac )
{
macBroadcaster.addListener( obj );
}else{
Mouse.addListener( obj );
}
}
 
/**
* Remove a listener
*/
public static function removeListener( obj:Object ):Void
{
if( isMac )
{
macBroadcaster.removeListener( obj );
}else{
Mouse.removeListener( obj );
}
}
 
private static function externalMouseEvent( delta:Number ):Void
{
macBroadcaster.broadcastMessage( "onMouseWheel", delta );
}
}

MouseWheel.addListener(this);

타임라인 상에 MouseWheel Class 를 사용하여 리스너를 생성한다.

<script type="text/javascript">script>

SWFObject 를 사용하여 swf 파일을 임베드하였다. 마지막 줄 코드만 삽입하면 html
상에서 플래시로 마우스 휠반응을 감지하여 값을 보낼수 있다.

Kimkijeung.com » wheel

SWFObject add-on: MouseWheel on Mac